^^&&^^

Edit File: builddovecotconf

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/builddovecotconf                  Copyright 2016 cPanel, Inc.
#                                                           All Rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

package scripts::builddovecotconf;

use strict;

use Cpanel::Config::LoadCpConf        ();
use Cpanel::AdvConfig                 ();
use Cpanel::AdvConfig::dovecot        ();
use Cpanel::AdvConfig::dovecot::utils ();
use Cpanel::Usage                     ();
use Cpanel::Exception                 ();
use Cpanel::FileUtils::TouchFile      ();
use Cpanel::Autodie::Unlink           ();
use Cpanel::FileUtils::Access         ();
use Cpanel::MailUtils::SNI            ();
use Cpanel::Mkdir                     ();
use Cpanel::Rand                      ();
use Cpanel::Rand::Get                 ();
use Cpanel::Dovecot                   ();
use DBI                               ();
use DBD::SQLite                       ();
use Cpanel::DBI::SQLite               ();

use Try::Tiny;

our $CONF_PERMS                           = 0644;
our $DOVECOT_SQLITE_EXPIRES_TEMPLATE_FILE = '/usr/local/cpanel/src/dovecot/dict.expires.sqllite.template';

__PACKAGE__->script(@ARGV) unless caller();

sub script {
    my ( $class, @args ) = @_;
    my $force        = 0;
    my $leave_broken = 0;
    my $now          = time();

Cpanel::Usage::wrap_options( \@args, \&usage, { 'force' => \$force, 'leave-broken' => \$leave_broken } );

my $cpconf_ref = Cpanel::Config::LoadCpConf::loadcpconf();

if ( $> != 0 ) {
        die "Insufficient permissions to rebuild dovecot.conf";
    }

my $dovecot_conf = Cpanel::AdvConfig::dovecot::utils::find_dovecot_conf();

my $test_dovecot_conf = Cpanel::Rand::get_tmp_file_by_name($dovecot_conf);
    die 'Failed to get a temporary working file!' if ( $test_dovecot_conf eq '/dev/null' );
    chmod( $CONF_PERMS, $test_dovecot_conf ) or die "Could not set permissions on $test_dovecot_conf: $!";

# make sure the local template is valid
    _check_local_template() if !$leave_broken;

my $values_to_change = _generate_config_and_check_syntax( $force, $test_dovecot_conf, $dovecot_conf, $leave_broken );

# If dovecot complained certain values are too low, we need to adjust them
    if ( scalar keys %$values_to_change ) {

_generate_config_and_check_syntax( $force, $test_dovecot_conf, $dovecot_conf, $leave_broken, $values_to_change );
    }

# This will be cached, so there's no big hit
    my $conf_hr = Cpanel::AdvConfig::dovecot::get_config();
    if ( $conf_hr->{'protocols'} =~ /imap(\s|$)/ ) {
        unlink '/var/cpanel/imap_tcp_check_disabled' if ( -e '/var/cpanel/imap_tcp_check_disabled' );
    }
    else {
        Cpanel::FileUtils::TouchFile::touchfile('/var/cpanel/imap_tcp_check_disabled') unless ( -e '/var/cpanel/imap_tcp_check_disabled' );
    }

_setup_dovecot_dirs();
    _setup_sqlite_dbs();

Cpanel::AdvConfig::dovecot::process_config_changes($conf_hr);

rename $test_dovecot_conf, $dovecot_conf;
    unlink $dovecot_conf . '.datastore';    # Just in case

try {
        Cpanel::MailUtils::SNI::rebuild_dovecot_sni_conf();
    }
    catch {
        warn "The system failed to rebuild Dovecot’s SNI configuration file:\n$_";
    };

return 1;
}

sub _generate_config_and_check_syntax {
    my ( $force, $test_dovecot_conf, $dovecot_conf, $leave_broken, $values_to_change ) = @_;

my $config_opts_hr = { 'service' => 'dovecot', 'force' => $force, '_target_conf_file' => $test_dovecot_conf };
    if ( $values_to_change and ref $values_to_change eq 'HASH' ) {
        $config_opts_hr->{'values_to_change'} = $values_to_change;
    }

my ( $returnval, $message ) = Cpanel::AdvConfig::generate_config_file($config_opts_hr);
    if ( !$returnval ) {
        print "Failed to build $dovecot_conf\n$message\n";
        unlink $test_dovecot_conf;
        exit 1;
    }

( $returnval, $message, my $new_values_to_change ) = Cpanel::AdvConfig::dovecot::check_syntax($test_dovecot_conf);

if ( !$returnval ) {
        print <<"EOM";
Configuration generation failed with the following message:

$message

EOM
        unless ($force) {
            unlink $test_dovecot_conf unless ($leave_broken);
            exit 1;
        }
    }

return $new_values_to_change;
}

sub usage {
    print <<EO_USAGE;
Usage: builddovecotconf [options]

Options:
      --help          Brief help message
      --force         Force installation of new conf file even if syntax check fails
      --leave-broken  Leave broken dovecot.conf on the disk so that it can be manually examined
EO_USAGE
    exit 0;
}

# Check the local template to make sure it is valid
sub _check_local_template {
    my $valid_or_not_found;
    try {
        $valid_or_not_found = Cpanel::AdvConfig::dovecot::check_if_local_template_is_valid();
    }
    catch {
        print Cpanel::Exception::get_string($_) . "\n";
        $valid_or_not_found = 1;
    };

return 1 if $valid_or_not_found;

my ( $local_template, $error ) = Cpanel::AdvConfig::dovecot::get_template_file();
    if ( !$local_template ) {
        print $error . "\n";
        return;
    }

my $attempts        = 1;
    my $broken_template = _generate_broken_local_template_name($local_template);
    while ( -e $broken_template && $attempts < 11 ) {
        sleep(1);
        $broken_template = _generate_broken_local_template_name($local_template);
    }

if ( -e $broken_template ) {
        print "The local template file '$local_template' is invalid, but the system was unable to determine an unused filename to rename it to.\n";
        return;
    }

print "The local template file '$local_template' is invalid. The system will rename it to $broken_template.\n";

# yes, there is a small race condition here, but I'm betting we never hit it unless we start calling this script a lot more
    rename $local_template, $broken_template;

return;
}

sub _generate_broken_local_template_name {
    my ($local_template) = @_;

return $local_template . '.broken.' . time . '.' . Cpanel::Rand::Get::getranddata(16);
}

sub _get_expires_dbh {
    return Cpanel::DBI::SQLite->connect(
        {
            db                => $Cpanel::Dovecot::SQLITE_EXPIRES_DB_FILE,
            sqlite_open_flags => DBD::SQLite::OPEN_READWRITE(),
        }
    );
}

sub _setup_dovecot_dirs {
    Cpanel::Mkdir::ensure_directory_existence_and_mode( $Cpanel::Dovecot::CP_DOVECOT_STORAGE, 0770 );
    Cpanel::FileUtils::Access::ensure_mode_and_owner( $Cpanel::Dovecot::CP_DOVECOT_STORAGE, 0770, 'dovecot' );
    Cpanel::Mkdir::ensure_directory_existence_and_mode( $Cpanel::Dovecot::LASTLOGIN_DIR, 0700 );
    Cpanel::FileUtils::Access::ensure_mode_and_owner( $Cpanel::Dovecot::LASTLOGIN_DIR, 0700, 'dovecot' );
    return 1;
}

sub _setup_sqlite_dbs {
    my ($expires_dbh);

#TODO: Replace raw DBI with Cpanel::DBI::SQLite.
    if ( !-e $Cpanel::Dovecot::SQLITE_EXPIRES_DB_FILE || -z _ || !eval { $expires_dbh = _get_expires_dbh() } ) {
        system '/bin/cp', '-f', $DOVECOT_SQLITE_EXPIRES_TEMPLATE_FILE, $Cpanel::Dovecot::SQLITE_EXPIRES_DB_FILE;
    }
    Cpanel::FileUtils::Access::ensure_mode_and_owner( $Cpanel::Dovecot::SQLITE_EXPIRES_DB_FILE, 0660, 'dovecot' );
    Cpanel::Autodie::Unlink::unlink_if_exists($Cpanel::Dovecot::SQLITE_LASTLOGIN_DB_FILE);

$expires_dbh ||= _get_expires_dbh();
    if ( !$expires_dbh ) {
        print "Cannot connect to SQLite DB: $Cpanel::Dovecot::SQLITE_EXPIRES_DB_FILE: $DBI::errstr\n";
        return 1;
    }

return 1;
}