^^&&^^

Edit File: horde_mysqltosqlite

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/horde_mysqltosqlite               Copyright 2015 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use Cpanel::DNSONLY                               ();
use Cpanel::Horde::MySQLToSQLite                  ();
use Cpanel::iContact::Class::Horde::MySQLToSQLite ();
use Cpanel::Locale 'lh';
use Cpanel::Logger::Persistent       ();
use Cpanel::Horde::Legacy::MySql     ();
use Cpanel::Horde::RepairSchema      ();
use Cpanel::RPM::Versions::Directory ();
use Cpanel::MysqlUtils::Connect      ();
use Cpanel::MysqlUtils::MyCnf::Full  ();
use Cpanel::PwCache                  ();
use Getopt::Long                     ();

use Try::Tiny;

# This manual setting of HOME is required because:
#  - Running from queueprocd strips HOME
#  - Some of the MySQL stuff uses the standalone mysql binaries, which require HOME to be set to load root's .my.cnf
$ENV{'HOME'} = Cpanel::PwCache::gethomedir('root');

my @additional_failure_info;

my $logger = Cpanel::Logger::Persistent->new( { 'alternate_logfile' => $Cpanel::Horde::Legacy::MySql::CONVERSION_LOG_FILE } );

# CLI stuff
sub _run {
    my @args        = @_;
    my $exit_status = 0;
    try {
        $exit_status = __PACKAGE__->run(@args);
    }
    catch {
        my $exception = $_;

# Non-fatal errors gathered earlier in the conversion (and already logged when they occurred)
        # that should still be part of the final report if the conversion does fail overall.
        if (@additional_failure_info) {
            $exception .= <<EOM;

------------------------
Additional failure info:

@{[ join( "\n\n", @additional_failure_info ) ]}
EOM
        }

$logger->warn( lh()->maketext( 'The conversion of [asis,Horde] [asis,MySQL] data to [asis,SQLite] failed: [_1]', $exception ) );
        Cpanel::iContact::Class::Horde::MySQLToSQLite->new( detail => $exception );
        exit 1;
    };
    exit( $exit_status || 0 );
}

_run(@ARGV) unless caller;

# Public api for unit tests.
sub run {
    my @args = @_;

# These options are used if the user does not provide
    # any flags in their command-line call.
    my $opts = {
        users        => [],
        backup       => 1,    # Enable the backup by default.
        force_backup => 0,    # Disable force backup if it already exists by default.
        fix          => 1,    # Enable the schema repair by default.
        drop         => 1,    # Drop the database by default.
        force_drop   => 0,    # Disable force drop by default. Only applies if called with
                              # users specified and there are no failures. --drop is sufficient
                              # to cleanup the db when all users are converted.
        convert      => 1,    # Enable conversion by default.
        verbose      => 0,    # Verbose output is disabled by default.
    };

my $getopt_status = Getopt::Long::GetOptionsFromArray(
        \@args,
        'user:s{,}'        => $opts->{users},              # its already a reference
        'backup!'          => \$opts->{backup},
        'force-backup!'    => \$opts->{force_backup},
        'fix-schema!'      => \$opts->{fix},
        'convert!'         => \$opts->{convert},
        'drop!'            => \$opts->{drop},
        'force-drop!'      => \$opts->{force_drop},
        'replace-dest-db!' => \$opts->{replace_dest_db},
        'verbose'          => \$opts->{verbose},
        'help'             => \$opts->{help},
    );
    if ( $opts->{help} ) {
        _print_usage();
        return 0;
    }
    elsif ( !$getopt_status ) {
        _print_usage();
        return 1;
    }

# check_rpm_versions() will return false if horde is set to uninstalled / unmanaged.
    # We don't treat this as a failure, just a skip condition.
    return 0 if !check_rpm_versions();

# will throw an exception on failure
    check_for_innodb();

if ( !have_horde_db() ) {
        $logger->info( lh()->maketext(q{You do not have a [asis,Horde] [asis,MySQL] database. The system does not require [asis,Horde] data conversion.}) );
        return 0;
    }

if ( Cpanel::DNSONLY::enabled() ) {
        $logger->info( lh()->maketext(q{This is a DNSONLY server. The system does not require [asis,Horde] data conversion.}) );
        return 0;
    }

# Backup the mysql horde database in it current condition
    if ( $opts->{backup} ) {
        if ( !Cpanel::Horde::Legacy::MySql::does_final_backup_exist() || $opts->{force_backup} ) {

if ( Cpanel::Horde::Legacy::MySql::does_final_backup_exist() && $opts->{force_backup} ) {
                $logger->info( lh()->maketext('The system will replace the current backup of the [asis,pre-11.50] [asis,Horde] [asis,MySQL] database.') );
            }
            else {
                $logger->info( lh()->maketext('The backup of the [asis,pre-11.50] [asis,Horde] [asis,MySQL] database is in progress.') );
            }

Cpanel::Horde::Legacy::MySql::create_final_backup();

$logger->info( lh()->maketext( 'The backup of the [asis,pre-11.50] [asis,Horde] [asis,MySQL] database is complete. The backup is located at: [_1]', $Cpanel::Horde::Legacy::MySql::MYSQL_FINAL_BACKUP ) );
        }
        else {
            die( lh()->maketext( 'The system cannot backup the [asis,pre-11.50] [asis,Horde] [asis,MySQL] database. A backup of the database already exists: “[_1]”.', $Cpanel::Horde::Legacy::MySql::MYSQL_FINAL_BACKUP ) );
        }
    }

my $converter = Cpanel::Horde::MySQLToSQLite->new( logger => $logger, replace_dest_db => $opts->{replace_dest_db} );

if ( $opts->{fix} ) {

# just in case a previous run left behind cruft
        $converter->cleanup_temp_tables();

eval {
            # will throw an exception on failure
            check_and_fix_1148_schema($opts);
        };
        if ( my $exception = $@ ) {
            $logger->warn($exception);

# Proceed on with the conversion, but save a quick note about what happened.
            push @additional_failure_info, lh()->maketext('The schema fixer failed to correct the [asis,MySQL] tables. When the conversion attempted to continue beyond this failure, another error occurred that caused it to abort. See [asis,/var/cpanel/logs/horde_mysqltosqlite_log] for more details.');
        }
    }

if ( $opts->{convert} ) {

$logger->info( lh()->maketext('The migration of [asis,Horde] data from the shared [asis,MySQL] database to individual account [asis,SQLite] databases is in progress.') );

# these will throw an exception on failure
        if ( @{ $opts->{users} } ) {
            $converter->convert_users( $opts->{users} );
        }
        else {
            $converter->convert_all_users();
        }

$logger->info( lh()->maketext('The system has completed the migration of the [asis,Horde] data to the individual account [asis,SQLite] databases.') );

if ( ( !@{ $opts->{users} } && $opts->{drop} ) || ( $opts->{drop} && $opts->{force_drop} ) ) {
            if ( !@{ $opts->{users} } ) {
                $logger->info( lh()->maketext('You have successfully migrated all of the [asis,Horde] data. The system will remove the [asis,MySQL] [asis, Horde] database.') );
            }
            else {
                $logger->info( lh()->maketext('You specified the [asis,--force-drop] option. The system will remove the [asis,Horde] [asis, MySQL] database.') );
            }
            Cpanel::Horde::Legacy::MySql::drop_db();
        }
    }

return 0;
}

sub _print_usage {
    print <<EOF;
Usage: $0 [--user=<name> ...]

--user          - string  - One or more space separated users to try to convert. If you do not provide any --user options, the script will attempt to convert all users.

Fine grain control of the conversion steps. The --force-* options are used to override safety measures built into the code. Use them cautiously.

--backup           - boolean - Perform a backup of the database before starting the conversion. Defaults to performing this backup.
  --no-backup        - boolean - Do not backup of the database before starting the conversion.

--convert          - boolean - Convert the users or all users if no user is provided. This is the default action.
  --no-convert       - boolean - Do not perform the conversion.

--fix-schema       - boolean - Perform repairs to the horde mysql database schema before starting the conversion.
  --no-fix-schema    - boolean - Do not perform repairs to the horde mysql database schema before starting the conversion.

--drop             - boolean - Drop the Horde MySQL database when successfully done with the conversion of all user or when successfully done converting requested users and the --force-drop flag is passed.
  --no-drop          - boolean - Do not drop the Horde MySQL database when done with the conversion.
  --force-drop       - boolean - If the --drop flag is set, but the script is called with specific users, providing this flag will drop the database when the conversion finishes. Only use this flag if you are sure you are done with all user conversions.

--replace-dest-db  - boolean - If set, the destination SQLite database will be backed up and replaced before attempting the conversion.

--verbose          - boolean - If set, more verbose output is generted.

--help             - boolean - If present will show this help message.

EOF
    return;
}

sub check_for_innodb {
    my $my_cnf = Cpanel::MysqlUtils::MyCnf::Full::etc_my_cnf();
    my $skip   = 0;
    foreach my $var (qw/skip-innodb skip_innodb disable-innodb disable_innodb/) {
        $skip ||= exists $my_cnf->{'mysqld'}{$var} && $my_cnf->{'mysqld'}{$var} !~ /^(OFF|0)$/i;
    }
    my $innodb = $my_cnf->{'mysqld'}{'innodb'} && $my_cnf->{'mysqld'}{'innodb'} =~ /^(OFF|0)$/i;

die "Horde cannot be migrated because InnoDB is disabled.\n" if $skip || $innodb;
    return;
}

sub check_rpm_versions {
    my $rpms = Cpanel::RPM::Versions::Directory->new;
    my $state = $rpms->fetch( { 'section' => 'target_settings', 'key' => 'horde' } );

# customer is on its own, and explicitely does not want a cPanel support
    foreach my $setting (qw/unmanaged uninstalled/) {
        if ( $state && $state eq $setting ) {
            $logger->warn("Horde cannot be migrated because Horde is set to $setting.");
            return 0;
        }
    }

return 1;
}

sub check_and_fix_1148_schema {
    my ($opts) = @_;
    my $repairman = Cpanel::Horde::RepairSchema->new( verbose => $opts->{verbose} );
    if ( !$repairman->is_horde_1148_schema_correct() ) {
        $logger->info( lh()->maketext('The [asis,Horde] [asis,MySQL] database schema does not match the pristine [asis,11.48] [asis,Horde] schema. The system will attempt to repair the schema.') );
        $repairman->repair_horde_1148_mysql();
        $logger->info( lh()->maketext('The system has successfully repaired the [asis,Horde] [asis,MySQL] database schema.') );
    }
    return;
}

# have_horde_db()
#
#   - Returns true if the horde database is known to be present.
#   - Returns false if the horde database is known to be absent.
#   - Throws an exception if the presence or absence of the horde database could not be determined.
#
# Do this check rather than just trying to connect to the horde database so that unrelated
# MySQL errors aren't interpreted as the database being absent.
sub have_horde_db {

my ( $found_any_databases, $found_horde_database );

eval {
        my $obj  = Cpanel::MysqlUtils::Connect->new();
        my $dbh  = $obj->db_handle();
        my $rows = $dbh->selectall_arrayref('SELECT `SCHEMA_NAME` FROM `information_schema`.`SCHEMATA`');
        if ( 'ARRAY' eq ref $rows ) {
            for (@$rows) {
                my $db_name = $_->[0];
                $found_any_databases = 1;
                if ( $db_name eq 'horde' ) {
                    $found_horde_database = 1;
                }
            }
        }
    };
    my $exception = $@;

if ($found_any_databases) {
        return 1 if $found_horde_database;
        return 0;
    }

die qq{Due to a MySQL error, we couldn't determine whether the horde database is present: $exception};
}