^^&&^^

Edit File: cleandns

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - cleandns                                  Copyright 2010 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use Getopt::Std;
use File::Basename            ();
use Cpanel::SafeFile          ();
use Cpanel::RcsRecord         ();
use Cpanel::DNSLib            ();
use Cpanel::Hostname          ();
use Cpanel::FileUtils::Move   ();
use Cpanel::FileUtils::Copy   ();
use Cpanel::Logger            ();
use Cpanel::SafetyBits        ();
use Cpanel::StringFunc        ();
use Cpanel::StringFunc::Match ();

my $logger = Cpanel::Logger->new();

# Verbose variable, if set to "1" actions are reported to STDOUT.
my $cpverbose = 0;
my $restart   = 0;

my %options;
getopts( 'vr', \%options );
if ( defined( $options{'v'} ) ) { $cpverbose = 1; }
if ( defined( $options{'r'} ) ) { $restart   = 1; }

my $dnslib    = Cpanel::DNSLib->new();
my $namedconf = $dnslib->{'namedconf'};

my ( $confstatus, $confresult ) = $dnslib->checknamedconf();

if ( !$confstatus ) {
    print "Fatal! $namedconf fails named-checkconf, please repair named.conf and try again\n";
    chomp $confresult;
    print $confresult . "\n";
    exit 1;
}

Cpanel::RcsRecord::rcsrecord( $namedconf, 'cleandns BEGIN' );

my %ZONES;
my $inc        = 0;
my $numbrace   = 0;
my $zonemarker = 0;
my $cppcomment = 0;
my $seenhint   = 0;
my $zone       = '';
my $zonedir    = $dnslib->{'data'}{'zonefiledir'};
my $binduser   = $dnslib->{'data'}{'binduser'};
my $bindgrp    = $dnslib->{'data'}{'bindgroup'};

# Read through named.conf. Gather hash of zones and zone files
open( NDC, '<', $namedconf ) || die "Unable to open $namedconf: $!";

while (<NDC>) {

# Rudamentary comment exclusion.
    if ($cppcomment) {
        if (m/\*\//) {
            $cppcomment = 0;
        }
        next;
    }
    if (m/^\s*\#/) {
        next;
    }
    if (m/^\s\/\//) {
        next;
    }
    if (m/^\s*\/\*/) {
        $cppcomment = 1;
        next;
    }

if ($zonemarker) {
        $numbrace += Cpanel::StringFunc::get_curly_brace_count($_);
        if ( $numbrace == 0 ) {
            $zonemarker = 0;
        }
        if (m/.*[\s\t\;\{]file\s+["']([^"']+)/) {
            my $file        = $1;
            my $relativedir = '';
            if ( !Cpanel::StringFunc::Match::beginmatch( $file, '/' ) ) {
                if ( $file =~ m/^([^\/]+)/ ) {
                    $relativedir = $1;
                }
            }
            if ( -e $file ) {
                $ZONES{$zone} = $file;
            }
            else {
                my $filename = File::Basename::basename($file);
                my $filenew  = $zonedir . '/' . $filename;
                if ( -e $filenew ) {
                    $ZONES{$zone} = $filenew;
                }
                elsif ( $relativedir ne ''
                    && -e $zonedir . '/' . $relativedir . '/' . $filename ) {
                    $ZONES{$zone} = $zonedir . '/' . $relativedir . '/' . $filename;
                }
                elsif ( -e '/' . $file ) {
                    $ZONES{$zone} = '/' . $file;
                }
                else {
                    $ZONES{$zone} = '';
                }
            }
            next();
        }
        if (m/.*[\s\t\;\{]type\s+slave/) {
            delete( $ZONES{$zone} );
        }
    }
    if (m/\s*zone\s+["']([^"']+)/) {
        $zone       = $1;
        $zonemarker = 1;
        $numbrace += Cpanel::StringFunc::get_curly_brace_count($_);

if (m/.*[\s\t\;\{]file\s+["']([^"']+)/) {
            my $file        = $1;
            my $relativedir = '';
            if ( !Cpanel::StringFunc::Match::beginmatch( $file, '/' ) ) {
                if ( $file =~ m/^([^\/]+)/ ) {
                    $relativedir = $1;
                }
            }
            if ( -e $file ) {
                $ZONES{$zone} = $file;
            }
            else {
                my $filename = File::Basename::basename($file);
                my $filenew  = $zonedir . '/' . $filename;
                if ( -e $filenew ) {
                    $ZONES{$zone} = $filenew;
                }
                elsif ( $relativedir ne ''
                    && -e $zonedir . '/' . $relativedir . '/' . $filename ) {
                    $ZONES{$zone} = $zonedir . '/' . $relativedir . '/' . $filename;
                }
                elsif ( -e '/' . $file ) {
                    $ZONES{$zone} = '/' . $file;
                }
                elsif ( $zone eq '.' ) {
                    Cpanel::FileUtils::Copy::safecopy( '/usr/local/cpanel/scripts/named.ca', $filenew );
                    Cpanel::SafetyBits::safe_chown( $binduser, $bindgrp, $filenew );
                    $ZONES{$zone} = $filenew;
                }
                else {
                    $ZONES{$zone} = '';
                }
            }
            next;
        }
    }

if ( !$zonemarker ) {
        next;
    }
    else {
        $numbrace += Cpanel::StringFunc::get_curly_brace_count($_);
        if ( $numbrace == 0 ) {
            $inc = 0;
        }
    }
}
close(NDC);

if ($cpverbose) {
    print "The following zone and zonefiles were found\n";
    print "zones with out corresponding zone file will be removed\n";
    print "========================================================\n";
    foreach my $key ( sort keys %ZONES ) {
        print "$key ==> $ZONES{$key}\n";
    }
    print "========================================================\n";
}

$zone = '';
my @CONF;
$numbrace   = 0;
$zonemarker = 0;
$cppcomment = 0;

Cpanel::FileUtils::Copy::safecopy( $namedconf, $namedconf . '.precleandns' );

# Modify named.conf and remove bad entries.
my $namelock = Cpanel::SafeFile::safeopen( \*NDC, "+<", $namedconf );
if ( !$namelock ) {
    $logger->die("Could not edit $namedconf");
}

while (<NDC>) {

# Pass over comments
    if ($cppcomment) {
        if (m/\*\//) {
            $cppcomment = 0;
        }
        push @CONF, $_;
        next;
    }
    if (m/^\s*\#/) {
        push @CONF, $_;
        next;
    }
    if (m/^\s\/\//) {
        push @CONF, $_;
        next;
    }
    if (m/^\s*\/\*/) {
        $cppcomment = 1;
        push @CONF, $_;
        next;
    }

if ($zonemarker) {
        $numbrace += Cpanel::StringFunc::get_curly_brace_count($_);
        if ( $numbrace == 0 ) {
            $zonemarker = 0;
        }
        if ( defined( $ZONES{$zone} ) && $ZONES{$zone} eq '' ) {
            next;
        }
        elsif ( !defined( $ZONES{$zone} ) ) {
            push @CONF, $_;
            next;
        }
        elsif (m/(.*[\s\t\;\{])file\s+["']/) {
            my $space = $1;
            push @CONF, $space . "file \"$ZONES{$zone}\"\;\n";
            next;
        }
        else {
            push @CONF, $_;
            next;
        }
    }
    if (m/\s*zone\s+["']([^"']+)/) {
        $zone       = $1;
        $zonemarker = 1;
        $numbrace += Cpanel::StringFunc::get_curly_brace_count($_);
        if ( defined( $ZONES{$zone} ) && $ZONES{$zone} eq '' ) {
            next();
        }
        elsif ( !defined( $ZONES{$zone} ) ) {
            push( @CONF, $_ );
            next();
        }
        elsif (m/(.*[\s\t\;\{])file\s+["']/) {
            my $space = $1;
            push @CONF, $space . "file \"$ZONES{$zone}\"\;\n";
            next;
        }
        else {
            push @CONF, $_;
            next;
        }
    }

if ( !$zonemarker ) {
        push @CONF, $_;
    }
}

my $numzones = scalar keys %ZONES;

seek( NDC, 0, 0 );

my $deadline = 0;
foreach (@CONF) {
    if (m/^[\r\n\s\t]*$/) {
        $deadline++;
    }
    else {
        $deadline = 0;
    }
    if ( $deadline < 2 ) {
        print NDC $_;
    }
}
print NDC "\n";

truncate( NDC, tell(NDC) );
Cpanel::SafeFile::safeclose( \*NDC, $namelock );

( $confstatus, $confresult ) = $dnslib->checknamedconf();

if ( !$confstatus ) {
    print "!! cleandns was unable to properly clean $namedconf\n";
    print "!! Reverting to original version.\n";
    Cpanel::FileUtils::Copy::safecopy( $namedconf, $namedconf . '.brokencleandns' );
    Cpanel::FileUtils::Move::safemv( "-f", $namedconf . 'precleandns', $namedconf );
    Cpanel::SafetyBits::safe_chown( $binduser, $bindgrp, $namedconf );
    exit;
}

my $shorthost = Cpanel::Hostname::shorthostname();
if ( !$shorthost ) {
    $shorthost = 'localhost';
    print "Your hostname is not properly set.\n";
}

print "Cleaned up " . $numzones . " zone(s) on $shorthost. \n";
Cpanel::RcsRecord::rcsrecord( $namedconf, 'cleandns END' );

if ($restart) {
    print "Restarting Bind using restartsrv\n";
    exec '/usr/local/cpanel/scripts/restartsrv', 'named';
}
elsif ($cpverbose) {
    print "Bind will not be restarted automatically.\n";
    print "To restart Bind run the following: /usr/local/cpanel/scripts/restartsrv_named\n";
}