^^&&^^

Edit File: restart_tailwatchd_if_updated

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/restart_tailwatchd_if_updated     Copyright 2012 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;

use Cpanel::PsParser ();

my @tailwatchd_procs = grep { $_->{'user'} eq 'root' && $_->{'command'} =~ m/^tailwatchd/ } @{ Cpanel::PsParser::fast_parse_ps() };
my @starttimes;

foreach my $proc (@tailwatchd_procs) {
    my $pid       = $proc->{'pid'};
    my $starttime = ( stat("/proc/$pid") )[10];
    push @starttimes, $starttime;
}

my $original_start_time = get_oldest_time( \@starttimes );

my @filemtimes = ( ( stat('/usr/local/cpanel/Cpanel/TailWatch.pm') )[9] );
opendir( my $td, '/usr/local/cpanel/Cpanel/TailWatch' );
while ( my $file = readdir($td) ) {
    next if ( $file !~ m/\.pm/ );
    push @filemtimes, ( stat( '/usr/local/cpanel/Cpanel/TailWatch/' . $file ) )[9];
}

my $newest_file_mtime = get_newest_time( \@filemtimes );

if ( $original_start_time <= $newest_file_mtime ) {
    print "tailwatchd has newer code than the current running version.  Restarting\n";
    exec '/usr/local/cpanel/scripts/restartsrv_tailwatchd';
}
else {
    print "tailwatchd is running with the most current code.\n";
}

sub get_newest_time {
    my $time_ref = shift;

return ( sort { $b <=> $a } @{$time_ref} )[0];
}

sub get_oldest_time {
    my $time_ref = shift;

return ( sort { $a <=> $b } @{$time_ref} )[0];
}