^^&&^^

Edit File: xferpoint

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - xferpoint                                 Copyright 2015 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use Cpanel::AcctUtils    ();
use Cpanel::DomainTools  ();
use Cpanel::Hostname     ();
use Cpanel::Validate::IP ();

our $VERSION = '0.5';
if ( $ARGV[0] eq '--version' ) {
    print "VERSION: $VERSION\n";
    exit;
}

my $user        = shift(@ARGV);
my $sourceip    = shift;
my $destip      = shift;
my $domain      = shift;
my $shared_ip   = shift;
my @nameservers = @ARGV;

my $hostname = Cpanel::Hostname::gethostname();

if ( !$user || !$sourceip || !$destip || !$domain || !$shared_ip ) {
    die "Usage: $0 user sourceip destip domain sharedip [nameserver1 nameserver2 ...]";
}

if ( !Cpanel::AcctUtils::accountexists($user) ) {
    die "The user '$user' doesn't exist.\n";
}

foreach my $ip ( $sourceip, $destip, $shared_ip ) {
    next if $ip == -1;
    if ( !Cpanel::Validate::IP::is_valid_ipv4($ip) ) {
        die "'$ip' is not a valid ip.\n";
    }
}

if ( !Cpanel::DomainTools::is_valid( $domain, { wildcard_disallowed => 1 } ) ) {
    die "'$domain' is not valid as a domain name.\n";
}

if ( @nameservers && scalar @nameservers < 2 ) {
    die "There must be at least two nameservers given.\n";
}

print "[xferpoint] server:$hostname user:$user\n";
system '/usr/local/cpanel/scripts/xfertool', '--disallowlogins',      $user;
system '/usr/local/cpanel/scripts/xfertool', '--blockdynamiccontent', $user;
system '/usr/local/cpanel/scripts/xfertool', '--setupmaildest',       $user, 'secondary';

if ( -x '/usr/local/cpanel/bin/swapip' ) {
    system '/usr/local/cpanel/bin/swapip', $sourceip, $destip, $shared_ip, $domain;
}

if (@nameservers) {
    foreach my $dns (@nameservers) {
        if ( !Cpanel::DomainTools::is_valid($dns) ) {
            die "$dns is not valid.\n";
        }
    }
    system '/usr/local/cpanel/scripts/xfertool', '--changenameservers', $user, @nameservers;
}
else {
    print "[xferpoint] not updating nameservers (none provided)\n";
}

print "[xferpoint] complete\n";