^^&&^^

Edit File: mysqlconnectioncheck

#!/usr/local/cpanel/3rdparty/bin/perl
#
package scripts::mysqlconnectioncheck;
#
# cpanel - scripts/mysqlconnectioncheck              Copyright 2015 cPanel, Inc.
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use warnings;

use IO::Handle ();

use Cpanel::Finally          ();
use Cpanel::MysqlUtils       ();
use Cpanel::SafeFile         ();
use Cpanel::Hostname         ();
use Cpanel::Exception::Utils ();
use Cpanel::Exception        ();
use Cpanel::Mysql::Error     ();
use Cpanel::SafeRun::Object  ();
use Try::Tiny;

our $service                  = 'mysqlconnectioncheck';
our @reason_is_cannot_connect = (
    Cpanel::Mysql::Error::CR_CONNECTION_ERROR(),
    Cpanel::Mysql::Error::CR_CONN_HOST_ERROR(),
);

my $ret = __PACKAGE__->script();

exit(1) if !$ret;
exit(0);

sub script {

# Restartsrv will call mysqlconnectioncheck
    # In order to avoid this locking forever
    # we have a check to see if we are calling ourselves
    return 0 if ( $ENV{'MYSQLCCHK'} && $ENV{'MYSQLCCHK'} eq '1' );
    local $ENV{'MYSQLCCHK'} = 1;

my $hostname        = Cpanel::Hostname::gethostname();
    my $dbhost          = Cpanel::MysqlUtils::getmydbhost('root') || 'localhost';
    my $dbpassword      = Cpanel::MysqlUtils::getmydbpass('root');                                           # read from /root/.my.cnf
    my $is_remote_mysql = Cpanel::MysqlUtils::is_remote_mysql();
    my $lock_fh         = IO::Handle->new();
    my $lock_obj        = Cpanel::SafeFile::safeopen( $lock_fh, '>', "/var/cpanel/mysqlconnectioncheck" );
    my $mainpid         = $$;

if ( !$lock_obj ) {
        print "Could not get a lock on '/var/cpanel/mysqlconnectioncheck': $!\n";
        return;
    }

my $close_lock_cr = sub {
        return if $$ != $mainpid;
        if ( fileno $lock_fh ) {
            Cpanel::SafeFile::safeclose( $lock_fh, $lock_obj );
        }
    };

# in case we die
    my $finally = Cpanel::Finally->new($close_lock_cr);

if ( !$dbpassword ) {
        attempt_password_set();
    }

my ( $connection_ok, $connection_failure_reason, $connection_failure_message ) = check_mysql_connection();
    my $notify_data = {
        'hostname'        => $hostname,
        'is_remote_mysql' => $is_remote_mysql,
        'dbhost'          => $dbhost,
        'dbpassword'      => ( $dbpassword || '' ),
        'error'           => $connection_failure_message,
        'root_my_cnf'     => '/root/.my.cnf'                # move to Cpanel::ConfigFiles after 11.42 backport
    };
    if ( $connection_ok || $connection_failure_reason eq 'cannot_connect' ) {
        $close_lock_cr->();
        return 1;
    }
    elsif ( $connection_failure_reason eq 'access_denied' ) {
        if ($is_remote_mysql) {
            _notify( 'cannot_reset_remote_pass', $notify_data );
        }
        else {
            attempt_password_reset($notify_data);
            $close_lock_cr->();
            return 1;
        }
    }
    else {
        _notify( 'unknown_error', $notify_data );
    }

$close_lock_cr->();
    return 0;
}

sub attempt_password_set {
    require IPC::Open3;
    require Cpanel::MysqlUtils::ResetRootPassword;
    my $newpass = Cpanel::MysqlUtils::ResetRootPassword::get_root_password_that_meets_password_strength_requirements();

print "No MySQL password set!\n";
    print "Attempting to set the MySQL root user's password.\n";

_save_passwd_in_my_cnf($newpass);

return 1;
}

sub _save_passwd_in_my_cnf {
    my ($newpass) = @_;

Cpanel::SafeRun::Object->new_or_die(
        program => '/usr/local/cpanel/scripts/mysqlpasswd',
        args    => ['--multistdin'],
        stdin   => "root\n$newpass\n\n",
        stdout  => \*STDOUT,
        stderr  => \*STDERR,
    );

_update_mysql_profile($newpass);

return;
}

sub attempt_password_reset {
    my ($notify_data) = @_;

require Cpanel::MysqlUtils::ResetRootPassword;
    require Cpanel::MysqlUtils::Integration;

my $newpass = Cpanel::MysqlUtils::ResetRootPassword::get_root_password_that_meets_password_strength_requirements();

my ( $reset_obj, $reset_ok, $reset_message );
    try {
        $reset_obj = Cpanel::MysqlUtils::ResetRootPassword->new( 'password' => $newpass );
    }
    catch {
        $reset_message = Cpanel::Exception::get_string($_);
    };
    if ( !$reset_message ) {
        ( $reset_ok, $reset_message ) = $reset_obj->reset();

if ($reset_ok) {
            _save_passwd_in_my_cnf($newpass);
        }
    }
    print "$reset_message\n" if $reset_message;

my ($connect_ok_second_time) = check_mysql_connection();
    if ($connect_ok_second_time) {
        _notify( 'reset_pass_successful', $notify_data );
        _update_mysql_profile($newpass);
        Cpanel::MysqlUtils::Integration::update_apps_that_use_mysql_in_background();
    }
    else {
        $notify_data->{'reset_error'} = $reset_message;
        _notify( 'reset_pass_failed', $notify_data );
    }

return 1;
}

sub _update_mysql_profile {
    my $newpass = shift;

try {
        require Cpanel::MysqlUtils::RemoteMySQL::ProfileManager;
        Cpanel::MysqlUtils::RemoteMySQL::ProfileManager->new()->update_local_profiles_if_needed($newpass);
    }
    catch {
        print 'Failed to update MySQL profile: ' . Cpanel::Exception::get_string($_) . "\n";
    };

return 1;
}

sub check_mysql_connection {
    my $connection_ok              = 0;
    my $connection_failure_reason  = 'unknown';
    my $connection_failure_message = 'unknown';

local $ENV{'USER'} = 'root';
    local $ENV{'HOME'} = 'root';
    local $ENV{'LANG'} = 'C';

local $@;    # TODO: Convert to Try::Tiny when this is not scheduled for backport to 11.42
    my $dbh = eval { Cpanel::MysqlUtils->new(); };
    my $err = $@;

if ( !$err ) {
        $connection_ok = 1;
    }
    else {
        $connection_failure_message = Cpanel::Exception::Utils::traceback_to_error($err);

my $err_code = $err->get('error_code');

if ( grep { $_ eq $err_code } @reason_is_cannot_connect ) {
            $connection_failure_reason = 'cannot_connect';
        }
        elsif ( !Cpanel::Mysql::Error::is_client_error_code($err_code) ) {
            $connection_failure_reason = 'access_denied';
        }
    }

return ( $connection_ok, $connection_failure_reason, $connection_failure_message );
}

sub _notify {
    my ( $action, $data ) = @_;

require Cpanel::Notify;
    require Cpanel::IP::Remote;
    return Cpanel::Notify::notification_class(
        'class'            => 'Check::MysqlConnection',
        'application'      => $service,
        'interval'         => 3600,
        'status'           => $action,
        'constructor_args' => [
            %{$data},
            'origin'            => $service,
            'action'            => $action,
            'source_ip_address' => Cpanel::IP::Remote::get_current_remote_ip(),
        ],
    );
}