^^&&^^

Edit File: update_dkim_keys

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - update_dkim_keys                          Copyright 2013 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

package Script::Update::DKIM::Keys;

use strict;
use warnings;

use Cpanel::Config::LoadUserDomains ();
use Cpanel::DnsUtils::AskDnsAdmin   ();
use Cpanel::DKIM                    ();
use Cpanel::Logger                  ();

__PACKAGE__->script(@ARGV) unless caller();

sub script {
    my ( $class, @argv ) = @_;

my $logger       = Cpanel::Logger->new();
    my $user_domains = Cpanel::Config::LoadUserDomains::loaduserdomains();
    return unless $user_domains;

my @users = sort keys %$user_domains;

# order is important
    my @to_skip = qw{SYNCZONES RELOADZONES};
    my $skipped = {};

my $original = \&Cpanel::DnsUtils::AskDnsAdmin::askdnsadmin;
    {
        # the idea behind that code is to avoid to run
        # SYNCZONES RELOADZONES more than one time when no special args are defined
        no warnings 'redefine';
        *Cpanel::DnsUtils::AskDnsAdmin::askdnsadmin = sub {
            my ( $type, @args ) = @_;
            foreach my $skip (@to_skip) {

# only skip action with args among { 0, '', undef }
                #	can probably factorize other requests
                if ( $type eq $skip && !grep { $_ } @args ) {
                    $skipped->{$type} = 1;
                    return;    # action skipped
                }
            }

# GETZONES or any other requests are ok
            return $original->(@_);
        };
    }

foreach my $user (@users) {
        $logger->info("regenerate dkim keys for user '$user'");

# do not enable skipreload as we want to peform one unique final reload if required
        Cpanel::DKIM::setup_domain_keys( user => $user, skipreload => 0 );
    }

# preserve order
    foreach my $todo (@to_skip) {
        next unless $skipped->{$todo};
        $logger->info("- run askdnsadmin $todo");
        $original->( $todo, 0 );
    }

return;
}