^^&&^^

Edit File: adddns

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - add_dns                                   Copyright 2015 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use warnings;
use Cpanel::DIp::MainIP  ();
use Cpanel::DnsUtils     ();
use Cpanel::DomainTools  ();
use Cpanel::Validate::IP ();
use Getopt::Long         ();

my ( $domain, $ip, $reseller, $allowoverwrite, $trueowner );

my $opts = Getopt::Long::GetOptions(
    'domain=s'   => \$domain,
    'ip=s'       => \$ip,
    'reseller=s' => \$reseller,
    'overwrite'  => \$allowoverwrite,
    'owner=s'    => \$trueowner
);

# Domain
if ( !$domain ) {
    show_usage();
    exit 1;
}
else {
    $domain = Cpanel::DomainTools::normalize($domain);
    if ( !Cpanel::DomainTools::is_valid($domain) ) {
        print "No valid domain specified.\n";
        show_usage();
        exit 1;
    }
}

# IP
if ( !$ip || !Cpanel::Validate::IP::is_valid_ipv4($ip) ) {
    $ip = Cpanel::DIp::MainIP::getmainip();
    print "No valid IP specified. Using $ip\n";
}

# Reseller
if ( !$reseller ) {
    $reseller = 'root';
}

# Allow Over Write
if ($allowoverwrite) {
    if ( $allowoverwrite =~ m/^n/i ) {
        $allowoverwrite = 0;
    }
    else {
        $allowoverwrite = 1;
    }
}
else {
    $allowoverwrite = 0;
}

$trueowner ||= 'root';

my ( $status, $error ) = Cpanel::DnsUtils::doadddns( 'domain' => $domain, 'ip' => $ip, 'reseller' => $reseller, 'trueowner' => $trueowner, 'allowoverwrite' => $allowoverwrite );
if ( !$status ) {
    print $error . "\n";
}

sub show_usage {
    print <<"EOM";
$0

Control Flags:
--domain    (required)
    Domain for zone creation

--ip        (optional)
    IP for zone creation. Defaults to server's main shared IP

--reseller  (optional)
    Set reseller (zone administrator) to utilize name server IPs assigned via WHM to the reseller.
    Defaults to using main server name server IPs

--owner     (optional)
    Account who will own the domain
    Defaults to root

--overwrite (optional)
    Allow overwrite of existing zones

EOM
    return;
}