^^&&^^

Edit File: cpanel_initial_install

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/cpanel_initial_install            Copyright 2017 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

package scripts::cpanel_initial_install;

use strict;
use warnings;

use Cpanel::AdvConfig::apache     ();
use Cpanel::CloudLinux            ();
use Cpanel::Chkservd::Manage      ();
use Cpanel::Config                ();
use Cpanel::Config::CpConfGuard   ();
use Cpanel::Config::FlushConfig   ();
use Cpanel::Config::LoadCpConf    ();
use Cpanel::ConfigFiles           ();
use Cpanel::EA4::Util             ();
use Cpanel::EasyApache            ();
use Cpanel::FastInstall           ();
use Cpanel::FileUtils::Copy       ();
use Cpanel::GenSysInfo            ();
use Cpanel::HttpUtils::Hostname   ();
use Cpanel::Kernel                ();
use Cpanel::RPM                   ();
use Cpanel::Usage                 ();
use Cpanel::NAT                   ();
use Cpanel::Sys::Hostname         ();
use Cpanel::Sys::Hostname::Modify ();
use Cwd                           ();
use File::Path                    ();
use Cpanel::HTTP::Client          ();
use IO::Handle                    ();
use IO::Select                    ();
use IPC::Open3                    ();
use Cpanel::Update::Logger        ();
use Cpanel::MariaDB               ();
use Cpanel::MariaDB::Install      ();
use Cpanel::SafeRun::Object       ();
use Cpanel::SysPkgs::YUM          ();
use Whostmgr::Services            ();
use Whostmgr::TweakSettings::Mail ();
use Whostmgr::TweakSettings::Main ();
use Cpanel::ServerTasks           ();    # a sub is overridden later in code so let's load it for safety.

use POSIX;

sub DEBUG($) { _MSG( 'DEBUG', "  " . shift ) }     # space pad debug messages.
sub ERROR($) { _MSG( 'ERROR', shift ) }
sub WARN($)  { _MSG( 'WARN',  shift ) }
sub INFO($)  { _MSG( 'INFO',  shift ) }
sub FATAL($) { _MSG( 'FATAL', shift ); exit 1; }

our $message_caller_depth              = 1;
our $yumcheck                          = 0;
our $install_legacy_ea3_instead_of_ea4 = "/etc/install_legacy_ea3_instead_of_ea4";
our $ea4_custom_profile                = '/etc/cpanel_initial_install_ea4_profile.json';
our $ea3_install_dir                   = '/usr/local/apache';

exit __PACKAGE__->script(@ARGV) unless caller();

sub script {
    my @ARGS = @_;

if ( !$ENV{'CPANEL_BASE_INSTALL'} ) {
        die("This program is designed to be run from the cpanel installer. It is probably destructive to run but if you insist, you'll need to set the environment variable CPANEL_BASE_INSTALL=1 before you run it\n");
    }

my $skip_apache  = 0;
    my $installstart = time();

my %opts = (
        'skipapache'   => \$skip_apache,
        'installstart' => \$installstart,
    );

Cpanel::Usage::wrap_options( \@ARGS, \&usage, \%opts );

my $lock_file = '/root/installer.lock';
    $| = 1;
    umask 022;

# Create the lock file.
    touch( $lock_file, $$ );

# Don't create the END block until run time.
    eval q{
        # Cleanup the lock file on exit.
        END {
            if ( $lock_file and open(my $fh, '<', $lock_file ) ) {
                my $pid = <$fh>;
                close $fh;

chomp $pid if ($pid);
                if ( !$pid or $pid == $$ ) {
                    print "Removing $lock_file\n";
                    unlink $lock_file;
                }
            }
        }
    };

# Open the install logs for append.
    open_logs();

# Determine local distro and version. Fail if unsupported.
    my ( $distro, $distro_version ) = check_system_support();

my $installer_dir = Cwd::getcwd();

# Now software is installed, call rdate in case it couldn't be called earlier.
    $installstart = update_system_clock($installstart);

# Setup 3rdparty/bin symlinks
    ssystem('/usr/local/cpanel/scripts/link_3rdparty_binaries');

{
        # Save the /var/cpanel/cpanel.config and cache file we've been avoiding up to this point.
        INFO("Setting up /var/cpanel/cpanel.config");
        local $ENV{CPANEL_BASE_INSTALL} = 0;
        Cpanel::Config::CpConfGuard::clearcache();
        Cpanel::Config::LoadCpConf::loadcpconf();
    }

# Set up swap if needed.
    set_up_swap();

# NAT auto-detection/configuration
    ssystem('/usr/local/cpanel/scripts/build_cpnat');

# Stop and possibly remove some services
    disable_and_remove_init_services();

# Init the package management system, update installed, then run sysup
    ensure_rpms_installed();

# Setup default cPanel users;
    setup_cpanel_system_users();

# Lowercase the host name if necessary (no need to fork anymore, this is now run by cpanel perl)
    Cpanel::Sys::Hostname::Modify::make_hostname_lowercase();

# Install MariaDB if necessary.
    install_mariadb();

# Run scripts/securemysql if necessary
    run_securemysql_ifnecessary();

# do roundcube finishing touches #
    run_roundcube_ifnecessary();

my $eximdb_run = Cpanel::SafeRun::Object->new(
        program => $^X,
        args    => [
            '-MCpanel::EximStats::ConnectDB',
            '-e' => 'Cpanel::EximStats::ConnectDB::dbconnect()',
        ],
        stdout => \*STDOUT,
        stderr => \*STDERR,
    );

warn $eximdb_run->autopsy() if $eximdb_run->CHILD_ERROR();

# Update license information ASAP so code can get at it.
    INFO "Updating license information";
    ssystem(qw{/usr/local/cpanel/cpkeyclt});

# Make touch files corresponding to cpanel.config settings.
    do_cpanel_config_touch_files();

# Upgrade to cloud linux if licensed via cpanel. Change distro if it updates.
    ( $distro, $distro_version ) = upgrade_to_cloud_linux( $distro, $distro_version );

if ( -e '/usr/sbin/pwconv' ) {
        INFO "making sure we are shadowed";
        ssystem('/usr/sbin/pwconv');
    }

INFO "Making sure cPanel processes are not running";
    foreach my $app (qw(cpsrvd cpdavd cphulkd)) {
        ssystem( '/usr/local/cpanel/etc/init/stop' . $app );
    }

# during first install Update::Now is extracting the locale tarball to /var/cpanel/locale
    if ( !Cpanel::FastInstall::is_enabled() ) {
        INFO("Setting up locale databases");
        ssystem('/usr/local/cpanel/bin/build_locale_databases');
    }

INFO("Making sure the firewall (if present) is setup for cPanel.");
    ssystem('/usr/local/cpanel/scripts/configure_firewall_for_cpanel');

INFO 'Securing the /tmp and /var/tmp directories.';
    ssystem( '/usr/local/cpanel/scripts/securetmp', '--auto', '--install' );

# used for EA and hulkd
    create_cpanel_directories();

INFO("Making sure the 3rd party services setup in cpanel.conf are properly enabled");
    setup_third_party_services( $distro, $distro_version );

INFO("Attending to Easy apache");
    install_apache( $skip_apache, $distro, $distro_version );

setup_misc_cpanel_config_files($distro_version);

setup_exim_config_defaults();

# Run upcp for the first time.
    # NOTE: This will start cpanellogd.
    INFO " ";
    INFO " ";
    INFO "Running upcp for the first time.";
    INFO " ";
    INFO " ";
    ssystem(qw{/usr/local/cpanel/scripts/upcp manual --force});

# Enable services for startup.
    # TODO: Add chkconfig to RPM spec entries and remove this code.
    my @services = qw/cpanel mysql sshd/;
    INFO 'Adding services to startup.';
    foreach my $service (@services) {
        INFO " - Enabling $service";
        ssystem( '/usr/local/cpanel/scripts/cpservice', $service, 'enable' );
    }

schdir($installer_dir);

# Restore any staged cpanel accounts
    cpanel_account_restore();

# enable cphulkd by default
    enable_cphulkd();

INFO "Automatically enabling features";
    ssystem(qw{/usr/local/cpanel/scripts/ensure_autoenabled_features --run});

# Tailwatchd should be started from the queue
    # to avoid a race condition where its already in the queue
    # and we try to start it.
    #
    # Previously we would start tailwatchd after
    # flushing the task queue which lead to a race
    # condition where the task queue might start it
    # and then restartsrv would try as well.  The one
    # that lost the race would error.  By putting it
    # in the queue we ensure we only do it once.
    eval { Cpanel::ServerTasks::queue_task( ['TailwatchTasks'], 'reloadtailwatch' ); };

INFO "Flushing the task queue";
    {
        local $ENV{CPANEL_BASE_INSTALL} = 0;
        ssystem(qw{/usr/local/cpanel/bin/servers_queue run});
    }

enable_autossl();

my $finishtime        = time();
    my $installtime       = $finishtime - $installstart;
    my $installfinishtime = localtime($finishtime);

INFO sprintf( "cPanel install finished in %d minutes and %d seconds!", int( $installtime / 60 ), $installtime % 60 );

display_howto();

# Check if the kernel set for boot matches what's currently running (uname -r)
    notify_if_boot_kernel_changed($distro);

if ( -x '/root/cpanel_profile/postinstallhook' ) {
        INFO "Running /root/cpanel_profile/postinstallhook";
        ssystem('/root/cpanel_profile/postinstallhook');
    }

return 0;
}

### ---- END sub script ---- ####

sub ssystem {
    my @cmd = @_;
    my $conf_hr = ref( $cmd[-1] ) eq 'HASH' ? pop(@cmd) : {};

local $message_caller_depth = $message_caller_depth + 1;    # Set caller depth deeper during this sub so debugging it clearer.
    DEBUG '- ssystem [BEGIN]: ' . join( ' ', @cmd );
    open( RNULL, '<', '/dev/null' );
    my $io = IO::Handle->new();
    my $pid = IPC::Open3::open3( "<&RNULL", $io, $io, @cmd );
    $io->blocking(0);

my $select = IO::Select->new($io);

my $exit_status;
    my $buffer                 = '';
    my $buffered_waiting_count = 0;
    while ( !defined $exit_status ) {
        while ( my $line = readline($io) ) {

# Push the buffer lacking a newline onto the front of this.
            if ($buffer) {
                $line   = $buffer . $line;
                $buffer = '';
            }

$line =~ s/\r//msg;    # Strip ^M from output for better log output.

if ( $yumcheck && $line =~ /yum might be hung/ ) {
                kill 15, $pid;
                sleep 2;
                WARN "....yum is hung, trying to restart it....";
                ssystem(qw/killall -TERM yum/);
                sleep(20);
                ssystem(qw/killall -TERM yum/);
            }

# Internally buffer on newlines.
            if ( $line =~ m/\n$/ms ) {
                DEBUG( "  " . $line );
                $buffered_waiting_count = 0;
            }
            else {
                print "." if ( $buffered_waiting_count++ > 1 );
                $buffer = $line;
            }
        }

# Parse exit status or yield time to the CPU.
        if ( waitpid( $pid, 1 ) == $pid ) {
            $exit_status = $? >> 8;
        }
        else {

# Watch the file handle for output.
            $select->can_read(0.1);
        }
    }
    DEBUG "  - ssystem [EXIT_CODE] '$cmd[0]' exited with $exit_status (ignored)" if ($exit_status);

close(RNULL);
    $io->close();

DEBUG '- ssystem [END]';

return $exit_status;
}

sub enable_autossl {
    return if is_dnsonly();

INFO 'Enabling AutoSSL';
    ssystem( '/usr/local/cpanel/bin/whmapi1', 'set_autossl_provider', 'provider=cPanel' );
    return;
}

sub schdir {
    my $dir = shift;
    my $cwd = Cwd::getcwd();
    chdir($dir) || die "Cannot chdir to ${dir}, cwd was: $cwd";

return;
}

sub create_cpanel_directories {

foreach my $d ( '/var/cpanel', '/var/cpanel/version' ) {
        mkdir $d, 0755 unless -e $d;
    }
    return;
}

sub ensure_rpms_installed {

unlink '/var/cpanel/useyum';    # No longer used by cPanel.

# Assure yum exclusions are reinstated
    unlink '/etc/checkyumdisable';
    ssystem('/usr/local/cpanel/scripts/checkyum');

# Re-run sysup/rpmup to make sure packages are up to date.
    ssystem('/usr/local/cpanel/scripts/rpmup');

return;
}

sub update_system_clock {
    my $installstart = shift;

my @rdate_bin =
        -x '/usr/local/cpanel/scripts/rdate' ? ('/usr/local/cpanel/scripts/rdate')
      : -x '/usr/bin/rdate'        ? ( '/usr/bin/rdate',        '-s', 'rdate.cpanel.net' )
      : -x '/usr/local/bin/rdate'  ? ( '/usr/local/bin/rdate',  '-s', 'rdate.cpanel.net' )
      : -x '/usr/local/sbin/rdate' ? ( '/usr/local/sbin/rdate', '-s', 'rdate.cpanel.net' )
      : -x '/bin/rdate'            ? ( '/bin/rdate',            '-s', 'rdate.cpanel.net' )
      :                              ();

# Complain if we don't have an rdate binary.
    if ( !@rdate_bin ) {
        ERROR("Could not set system clock. Missing an rdate binary");
        return;
    }

# Set the clock
    my $was = time();
    ssystem(@rdate_bin);
    my $now = time();
    INFO( "Clock set to: " . localtime($now) );
    my $change = $now - $was;

# Adjust the start time if it shifted more than 10 seconds.
    if ( abs($change) > 10 ) {
        WARN("Clock changed by $change seconds.");
        $installstart += $change;
        WARN( "Starting time adjusted to " . localtime($installstart) );
    }
    else {
        INFO("Clock changed by $change seconds");
    }

return $installstart;
}

sub set_up_swap {
    INFO 'Checking for sufficient memory or swap.';
    ssystem(qw{/usr/local/cpanel/bin/create-swap --if-needed --verbose});
}

sub setup_cpanel_system_users {
    INFO 'Creating default cPanel users.';
    my @cpanel_users = qw( cpanel );
    if ( !is_dnsonly() ) {
        push @cpanel_users, qw(
          cpanelcabcache
          cpanelphppgadmin
          cpanelrrdtool
        );
    }

foreach my $cpanel_user (@cpanel_users) {
        next if ( getpwnam($cpanel_user) );
        DEBUG " adding  $cpanel_user ...";
        ssystem( '/usr/local/cpanel/scripts/adduser', '-r', '--nochecks', '--noshell', $cpanel_user, '/var/cpanel/userhomes' );
    }

# can probably be removed with mailman RPM
    if ( !is_dnsonly() && !getpwnam('mailman') ) {    # Fix for broken mailman installer ( still needed )
        DEBUG " adding  mailman ...";
        ssystem( '/usr/local/cpanel/scripts/adduser', '-r', '--nochecks', '--noshell', 'mailman', $Cpanel::ConfigFiles::MAILMAN_ROOT );
    }

return;
}

sub install_mariadb {
    my $config = scalar Cpanel::Config::LoadCpConf::loadcpconf();

my $set_version = $config->{'mysql-version'};
    INFO("The 'mysql-version' key is set to: $set_version.");
    return if !Cpanel::MariaDB::version_is_mariadb($set_version);

local *STDOUT;
    open STDOUT, '>>&=', \*LOG;

my $logger = Cpanel::Update::Logger->new( { 'stdout' => 1, 'log_level' => 'info' } );

INFO("Installing MariaDB");
    my $maria_install_obj = Cpanel::MariaDB::Install->new( 'output_obj' => $logger );

INFO('Installing MariaDB Repo');
    $maria_install_obj->ensure_yum_can_use_mariadb_repo($set_version);

INFO('Installing MariaDB dependencies');
    $maria_install_obj->install_known_mariadb_deps($set_version);

INFO('Installing MariaDB RPMS');
    $maria_install_obj->install_mariadb_rpms($set_version);

INFO('Re-running updatenow to install database dependant RPMS.');
    ssystem(qw{/usr/local/cpanel/scripts/updatenow --sync});

return;
}

sub run_securemysql_ifnecessary {
    my $config = scalar Cpanel::Config::LoadCpConf::loadcpconf();

# Case 183601
    # only run if this is mysql, not mariadb
    my $set_version = $config->{'mysql-version'};
    INFO("The 'mysql-version' key is set to: $set_version.");
    return if Cpanel::MariaDB::version_is_mariadb($set_version);

INFO("Running /scripts/securemysql");
    ssystem(qw{/usr/local/cpanel/scripts/securemysql -qFa removelockntmp});
    INFO("/usr/local/cpanel/scripts/securemysql Done");

return;
}

sub run_roundcube_ifnecessary {
    my $rpm  = Cpanel::RPM->new();
    my $list = $rpm->qa('cpanel-roundcubemail');
    return if !$list->{'cpanel-roundcubemail'};
    local $ENV{'CPANEL_ROUNDCUBE_INSTALL_VERSION'} = $list->{'cpanel-roundcubemail'};
    INFO('Running /usr/local/cpanel/bin/update-roundcube-db');
    ssystem(qw{/usr/local/cpanel/bin/update-roundcube-db});
    INFO('/usr/local/cpanel/bin/update-roundcube-db Done');
}

sub upgrade_to_cloud_linux {
    DEBUG "Detecting if Cloud Linux is licensed through cpanel";

# Assure local::lib to /usr/bin/perl so perl modules can be installed to home directories.
    ssystem('/usr/local/cpanel/bin/install_locallib_loginprofile');

my $license_options = `/usr/local/cpanel/cpanel -F`;
    return @_ if ( $license_options !~ m/cloudlinux/ms );

my $cloud_installer = '/usr/local/cpanel/bin/cloudlinux_update';
    INFO("Upgrading your distro to Cloud Linux");
    if ( !-x $cloud_installer ) {
        WARN("Cannot convert your system to Cloud Linux without $cloud_installer");
    }
    else {
        ssystem($cloud_installer);
    }

# Re-check system to make sure we haven't moved to cloud linux
    return check_system_support();
}

sub setup_third_party_services {
    my ( $distro, $distro_version ) = @_;

my $config = scalar Cpanel::Config::LoadCpConf::loadcpconf();

# Setup the FTP server. Default to proftpd
    {
        my $target = $config->{'ftpserver'} || 'proftpd';
        $target = 'disabled' if ( is_dnsonly() );    # DNSONLY installs cannot set a custom ftp server.

my $no_anon_ftp = '/var/cpanel/noanonftp';
        unless ( -e $no_anon_ftp ) {
            INFO('Defaulting Anonymous FTP off');
            touch('/var/cpanel/noanonftp');          # Default
        }

INFO "Setting up FTP server to '$target'";
        if ( $target !~ m/^(disabled|proftpd|pure-ftpd)$/ ) {
            WARN "$target is an unsupported ftpserver. Will default to 'proftpd' instead";
            $target = 'proftpd';
        }
        ssystem( '/usr/local/cpanel/scripts/setupftpserver', '--force', $target );
    }

# Setup the name server. Default to bind
    {
        my $target = $config->{'local_nameserver_type'} || 'bind';
        INFO "Setting up name server to '$target'";
        if ( $target !~ m/^(disabled|bind|nsd|mydns)$/ ) {
            WARN "$target is an unsupported name server. Will default to 'bind' instead";
            $target = 'bind';
        }

if ( $target eq 'bind' && $distro =~ m/centos|redhat|cloudlinux/i ) {
            if ( -e '/etc/named.conf' ) {
                INFO "Saving /etc/named.conf, and rebuild with cPanel defaults";
                if ( rename '/etc/named.conf', '/etc/named.conf.precpanelinstall' ) {
                    ssystem('/usr/local/cpanel/scripts/rebuilddnsconfig');
                }
                else {
                    WARN "Unable to rebuild /etc/named.conf file";
                }
            }
        }

ssystem( '/usr/local/cpanel/scripts/setupnameserver', '--force', $target );
    }

# Setup the mail server.
    {
        my $target = $config->{'mailserver'};
        $target = 'disabled' if ( is_dnsonly() );    # DNSONLY installs cannot set a custom mail server.

INFO "Setting up mail server to '$target'";
        if ( $target !~ m/^(disabled|dovecot)$/ ) {
            WARN "$target is an unsupported mail server. Will default to 'dovecot' instead";
            $target = 'dovecot';
        }
        ssystem( '/usr/local/cpanel/scripts/setupmailserver', '--force', $target );
    }

return;
}

sub install_apache {
    my ( $skip_apache, $distro, $distro_version ) = @_;

return if ( is_dnsonly() );
    if ($skip_apache) {
        WARN "Skipping Apache installation due to command line request";
        return;
    }

INFO "Installing Apache...";

if ( -e $install_legacy_ea3_instead_of_ea4 || $distro_version < 6 ) {
        install_ea3();
    }
    else {
        install_ea4( $distro, $distro_version );
    }

return;
}

sub install_ea4 {
    my ( $distro, $distro_version ) = @_;
    my $do_cl = Cpanel::CloudLinux::installed();

# enable fileprotect - need --skip-ea3-check as is_ea4() will not be valid yet
    ssystem(qw{/usr/local/cpanel/scripts/enablefileprotect --skip-ea3-check});

my $syspkg = Cpanel::SysPkgs::YUM->new( {} );
    $syspkg->ensure_plugins_turned_on();

if ($do_cl) {

my $maj_ver = substr( $distro_version, 0, 1 );    # 6 or 7 not 6.x or 7.x.y … just in case!
        if ( $maj_ver != 6 && $maj_ver != 7 ) {
            ERROR "Cloudlinux is installed but the major version is not 6 or 7";
            return;
        }

INFO "ea4: installing CloudLinux public key and EA4 yum repo for v$maj_ver";
        my $cl_rpm_url = "http://repo.cloudlinux.com/cloudlinux/EA4/cloudlinux-ea4-release-latest-$maj_ver.noarch.rpm";
        if ( ssystem( "rpm", "-Uv", $cl_rpm_url ) ) {     # or -iv? also h or will that not work for ssystem() and look gross? YAGNI I reckon
            ERROR "Could not install $cl_rpm_url";
            return;
        }
    }
    else {
        INFO "ea4: installing public key and EA4 yum repo";    # essentially scripts::migrate_ea3_to_ea4::preliminary_work() but without exiting and more control of flow and output

INFO "  - ea4: installing public key";
        if ( ssystem( "rpm", "--import", $Cpanel::EA4::Util::public_key_url ) != 0 ) {
            ERROR "Could not import the public key";
            return;
        }

INFO "  - ea4: installing EA4 yum repo";
        if ( -e $Cpanel::EA4::Util::repo_file_path ) {
            $Cpanel::EA4::Util::repo_file_path = $Cpanel::EA4::Util::repo_file_path . "-" . time;

}
        my $res = Cpanel::HTTP::Client->new->mirror( $Cpanel::EA4::Util::repo_file_url, $Cpanel::EA4::Util::repo_file_path );
        if ( !$res->{success} ) {
            ERROR "Could not install EA4 yum repo";
            return;
        }
        if ( defined $distro && $distro eq 'amazon' ) {

# Edit the repo file and hardcode EA4.repo to use "6" as the releasever
            if ( open( my $repo_read_fh, '<', $Cpanel::EA4::Util::repo_file_path ) ) {
                my @file_contents = (<$repo_read_fh>);
                close($repo_read_fh);
                if ( open( my $repo_write_fh, '>', $Cpanel::EA4::Util::repo_file_path ) ) {
                    foreach my $line (@file_contents) {
                        $line =~ s/ea4-c\$releasever-/ea4-c6-/;
                        print {$repo_write_fh} $line;
                    }
                    close($repo_write_fh);
                }

# Make sure we have scl-utils from epel installed
                system( 'yum', '--enablerepo=epel', '-y', 'install', 'scl-utils' );
            }
        }

}

INFO "ea4: installing prereqs";

my @profile_rpms = $do_cl ? ( "ea-profiles-cpanel", "ea-profiles-cloudlinux" ) : ("ea-profiles-cpanel");
    if ( ssystem( "yum", "-y", "install", "yum-plugin-universal-hooks", @profile_rpms, "ea-cpanel-tools" ) != 0 ) {
        ERROR "Could not install prerequisite RPMs: yum-plugin-universal-hooks ea-profiles-cpanel ea-cpanel-tools";
        return;
    }

# TODO: Remove distiller usage with user story ZC-1813.  This will alleviate the
    # gross hackiness we're going through to generate /var/cpanel/conf/apache/main.
    INFO "ea4: setting up config data store";
    generate_apache_global_config_file();
    ssystem("mv $ea3_install_dir $ea3_install_dir.bak") if -e $ea3_install_dir;    # rename this just in case we're on a dirty system
    ssystem("mkdir -p $ea3_install_dir/conf");
    touch("$ea3_install_dir/conf/httpd.conf");
    ssystem("/usr/local/cpanel/bin/apache_conf_distiller --store-data --reset");    # this generates a harmless/known warning since httpd binary doesn't exist yet
    touch('/var/cpanel/conf/apache/success');                                       # --store-data doesn't create this for us

# and now put back the old dirty
    ssystem("rm -rf $ea3_install_dir");
    ssystem("mv $ea3_install_dir.bak $ea3_install_dir") if -e "$ea3_install_dir.bak";

Cpanel::HttpUtils::Hostname::update_datastore( hostname => Cpanel::Sys::Hostname::gethostname(), force => 1 );

INFO "ea4: enabling EasyApache 4 system-wide";
    ssystem("mkdir -p /etc/cpanel/ea4");
    touch("/etc/cpanel/ea4/is_ea4");

INFO "ea4: installation";
    my $file = '/etc/cpanel_initial_install_ea4_profile.json';
    my $default_profile = "/etc/cpanel/ea4/profiles/" . ( $do_cl ? "vendor/cloudlinux/default.json" : "cpanel/default.json" );
    if ( Cpanel::EA4::Util::profile_appears_valid($ea4_custom_profile) ) {
        INFO "  - ea4: installing local profile";
        if ( ssystem( "/usr/local/bin/ea_install_profile", "--install", $ea4_custom_profile ) != 0 ) {
            WARN "  - ea4: local profile failed, falling back to default";
            if ( ssystem( "/usr/local/bin/ea_install_profile", "--install", $default_profile ) != 0 ) {
                ERROR "Could not install default profile (fallback failed)";
                return;
            }
        }
        else {
            Cpanel::FileUtils::Copy::safecopy( $ea4_custom_profile, '/etc/cpanel/ea4/profiles/custom/' );    # has output if there is an issue, creates path if it does not exist yet
        }
    }
    else {
        INFO "  - ea4: $ea4_custom_profile exists but was not a valid profile" if -e $ea4_custom_profile;
        INFO "  - ea4: installing default profile";
        if ( ssystem( "/usr/local/bin/ea_install_profile", "--install", $default_profile ) != 0 ) {
            ERROR "Could not install default profile";
            return;
        }
    }
    return;
}

sub install_ea3 {
    generate_apache_global_config_file();

DEBUG "Moving /etc/httpd out of the way and pointing /etc/httpd to $ea3_install_dir";
    if ( -e '/etc/httpd' && !-e $ea3_install_dir ) {
        if ( !-l '/etc/httpd' && !-e '/etc/httpd.old' ) {
            ssystem( 'mv', '/etc/httpd', '/etc/httpd.old' );
        }
        else {
            unlink '/etc/httpd';
        }
    }
    ssystem("ln -sf $ea3_install_dir /etc/httpd");

DEBUG "Determining if a custom profile needs to be used";
    my $local_profile = '/etc/cp_easyapache_profile.yaml';
    my $ea_profile    = 'cpanel_default';
    my $use_custom_profile;
    if ( -s $local_profile ) {
        $ea_profile         = $local_profile;
        $use_custom_profile = 1;
    }

# install EA
    DEBUG "Running apache install scripts";
    ssystem( '/usr/local/cpanel/scripts/cpanel_easy_sanity_check', '--quiet' );
    my $need_to_build_apache;
    if (
           Cpanel::FastInstall::is_enabled()
        && !$use_custom_profile
        && -x "$ea3_install_dir/bin/httpd"

# CloudLinux needs to build EA manually to update any specific modules #
        && !Cpanel::CloudLinux::installed()

# CloudLinux might have been installed during the install process, we'll need to do a source compile of EA
        && !( !Cpanel::CloudLinux::nocloudlinux() && Cpanel::CloudLinux::licensed() )
      ) {
        DEBUG "Restore a precompiled version of EasyApache";

=pod

build httpd.conf using /var/cpanel/conf/apache/main
        1. update apache/main and change hostname

=cut

ssystem(qw{/usr/local/cpanel/bin/apache_conf_distiller --update --reset});
        Cpanel::HttpUtils::Hostname::update_datastore( hostname => Cpanel::Sys::Hostname::gethostname(), force => 1 );

# 2. regenerate httpd.conf (to update hostname)
        ssystem("/usr/local/cpanel/bin/build_apache_conf");

# 3. generate mod security database and config files
        ssystem("/usr/local/cpanel/bin/modsec_cpanel_conf_init");

# 4. enable fileprotect (required by suPHP)
        ssystem(qw{/usr/local/cpanel/scripts/enablefileprotect --skip-ea3-check});

ssystem(qw{/usr/local/cpanel/scripts/restartsrv_httpd --no-verbose});
        if ( $? == 0 ) {
            DEBUG("EasyApache successfully restored");
        }
        else {
            # safety rescue when we cannot restore EA tarball ( should not happen )
            WARN("Precompiled version of EasyApache failed to start, rebuilding EA.");
            $need_to_build_apache = 1;
        }

# now that we have restored EA we need to see if it's not the latest and do a source compile if not #
        # NOTE: if we fail to contact the remote server or another problem occurs, we'll let the version we restored stand #
        $need_to_build_apache = 1 if eval { return !Cpanel::EasyApache::is_up_to_date(); };
    }
    else {
        $need_to_build_apache = 1;
    }

if ($need_to_build_apache) {
        DEBUG "Building EasyApache with profile '$ea_profile'";

ssystem( 'touch', '/var/cpanel/version/install_compiled_ea' );
        ssystem( '/usr/local/cpanel/scripts/easyapache', "--profile=$ea_profile", '--build' );
    }

DEBUG "Symlink etc -> conf as long as conf isn't a symlink";
    if ( -d "$ea3_install_dir/conf" && !-l "$ea3_install_dir/conf" ) {
        symlink( 'conf', "$ea3_install_dir/etc" );
    }

return;
}

sub generate_apache_global_config_file {

# Required here to avoid warnings on new installs
    require Whostmgr::TweakSettings::Apache;

# Don't generate the file if it already exists
    # Although, on a new install it shouldn't
    if ( -e '/var/cpanel/conf/apache/local' ) {
        WARN "cPanel global Apache configuration file already exists";
        return;
    }
    INFO "Generating cPanel global Apache configuration file";

# Ensure that the enclosing path exists
    File::Path::make_path('/var/cpanel/conf/apache');

my %global_config;

# Generate a hash of the options and values using the defaults
    # in the same manner as the UI when going to the
    # Home » Service Configuration » Apache Configuration » Global Configuration
    # page for the first time and hitting save.
    foreach my $key ( keys %Whostmgr::TweakSettings::Apache::Conf ) {

my $section = $Whostmgr::TweakSettings::Apache::Conf{$key};

# Start with the default value
        my $value = $section->{'default'};

# Execute if it is a code ref rather than an actual value
        $value = $value->() if ref $value eq 'CODE';

# Format if need a formatter is specified
        if ( exists $section->{'format'} and ref $section->{'format'} eq 'CODE' ) {
            $value = $section->{'format'}->($value);
        }

# Check the value if such a function exists
        if ( exists $section->{'checkval'} and ref $section->{'checkval'} eq 'CODE' ) {
            $value = $section->{'checkval'}->($value);
        }

# If the value is a hash of options, ensure that the options not listed are set to zero
        if ( ref $value eq 'HASH' and exists $section->{'options'} and ref $section->{'options'} eq 'ARRAY' ) {

foreach my $option ( @{ $section->{'options'} } ) {
                $value->{$option} = 0 unless exists $value->{$option};
            }
        }

$global_config{$key} = $value;
    }

my $rc = Cpanel::AdvConfig::apache::save_main_item(%global_config);

if ( !$rc ) {
        WARN "Error generating cPanel global Apache configuration file";
    }

return;
}

sub setup_misc_cpanel_config_files {
    my ($distro_version) = @_;
    INFO 'Setting up misc cPanel config files.';

# FB Case about running this out of maintenance and into the install script
    DEBUG '  Running scripts/secureit';
    ssystem( '/usr/local/cpanel/scripts/secureit', '--fast' );

# rc.local is not run with systemd.
    if ( $distro_version < 7 ) {

# sync time on reboot.
        my $rc_local = '/etc/rc.d/rc.local';
        DEBUG '  Configuring rdate to run on reboot';
        if ( open my $rc_fh, '>>', $rc_local ) {
            print {$rc_fh} "/usr/local/cpanel/scripts/rdate &\n";
            close $rc_fh;
        }
    }

DEBUG '  Setting WHM theme to x';
    open( THEME, '>', '/var/cpanel/whmtheme' );
    print THEME 'x';
    close(THEME);

return;
}

sub setup_exim_config_defaults {

INFO 'Setting up exim default configuration options.';

# Load the initial config, if the config file exists,
    # if it does not exist, start with an empty hash.
    my $initial_config = Cpanel::Config::loadConfig( '/etc/exim.conf.localopts', undef, "=", undef, undef, 1 );
    $initial_config ||= {};

# Get all the initial config values that are not undefs
    my %config = map { $_ => $initial_config->{$_} }
      grep { defined $initial_config->{$_} }
      keys %{$initial_config};

# Fill the config with default values for any we don't already have
    # We don't want to step on any values already setup in the config file
    my $mail_conf = Whostmgr::TweakSettings::Mail::get_conf();
    foreach my $key ( sort keys %{$mail_conf} ) {

# Don't overwrite initial values
        next if exists $config{$key};

my $section = $Whostmgr::TweakSettings::Mail::Conf{$key};
        next unless exists $section->{'default'};

# Start with the default value
        my $value = $section->{'default'};

# Execute if it is a code ref rather than an actual value
        $value = $value->() if ref $value eq 'CODE';

$config{$key} = $value;

# Some of these have actions to trigger creation of touch-files or symlinks
        # See that the action gets run
        if ( exists $section->{'action'} and ref $section->{'action'} eq 'CODE' ) {

# Pass the value as both the new value and the old value since this is to
            # be the initial value and we don't want to trigger running updateuserdomains multiple times
            $section->{'action'}->( $value, $value );
        }
    }

# Write out all settings
    my $rc = Cpanel::Config::FlushConfig::flushConfig( '/etc/exim.conf.localopts', \%config, undef, undef, { 'sort' => 1 } );
    WARN 'Error writing exim default configuration options to:  /etc/exim.conf.localopts' unless $rc;

return;
}

sub os_service_restart {
    my $service = shift or die;

DEBUG "Restarting service $service";
    ssystem( '/usr/local/cpanel/scripts/cpservice', $service, 'restart' );

return;
}

sub cpanel_account_restore {
    my $acct_restore_file = '/etc/cpanelacctrestore';
    return if ( !-e $acct_restore_file );

INFO "Restoring Accounts.";
    sleep(2);

open( my $fh, $acct_restore_file );
    while (<$fh>) {
        s/\n//g;
        DEBUG "Restoring $_";
        ssystem( "/usr/local/cpanel/scripts/restorepkg", "$_" );
    }
    close($fh);

unlink($acct_restore_file);
}

sub enable_cphulkd {
    my $conf_dir     = '/var/cpanel/hulkd';
    my $enabled_file = "$conf_dir/enabled";

INFO "Enabling cphulkd ...";
    mkdir "$conf_dir", 0755 unless -e "$conf_dir";

if ( Whostmgr::Services::enable('cphulkd') ) {

# Set up monitoring by default.
        Cpanel::Chkservd::Manage::enable('cphulkd');
        INFO "Done";
    }
    else {
        WARN "Unable to enable cphulkd";
    }
}

sub notify_if_boot_kernel_changed {
    my $distro = shift || '';

my $boot_kernel = eval { Cpanel::Kernel::get_default_boot_version() };
    $boot_kernel = '' unless defined $boot_kernel;
    WARN $@ if $@;

my $current_kernel = Cpanel::Kernel::get_running_version();
    $current_kernel = '' unless defined $current_kernel;
    return if $current_kernel eq $boot_kernel;

WARN "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!";
    WARN "Your system kernel may have been updated.";
    WARN "Current kernel ($current_kernel) has been changed to: $boot_kernel";
    WARN "Before rebooting the system, please ensure that the installed kernel version is compatible with your deployment.";
    if ( $distro =~ m/cloud/i ) {
        WARN " ";
        WARN " ************************************************************************************************************";
        WARN " ";
        WARN "   NOTE: Because this is a Cloud Linux install, cPanel WILL NOT BE FULLY FUNCTIONAL until you reboot. ";
        WARN " ";
        WARN " ************************************************************************************************************";
        WARN " ";
    }
    WARN "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!";
}

sub _MSG {
    my $level = shift;
    my $msg = shift || '';
    chomp $msg;

my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) = localtime;
    my ( $package, $filename, $line ) = caller($message_caller_depth);
    my $stamp_msg = sprintf( "%04d-%02d-%02d %02d:%02d:%02d %4s (%5s): %s\n", $year + 1900, $mon + 1, $mday, $hour, $min, $sec, $line, $level, $msg );

print LOG $stamp_msg;
    print $stamp_msg;
}

sub check_system_support {
    my $distro         = Cpanel::GenSysInfo::get_rpm_distro();
    my $distro_version = Cpanel::GenSysInfo::get_rpm_distro_version();

return ( $distro, $distro_version );
}

sub open_logs {
    my $log_file = '/var/log/cpanel-install.log';
    open( LOG, '>>', $log_file );
    select(LOG);
    $| = 1;

select(STDOUT);
}

sub is_dnsonly {
    return -e '/var/cpanel/dnsonly' ? 1 : 0;
}

sub os_service_stop {
    my $service = shift or die;

DEBUG "Ensuring service $service is not running";
    ssystem( '/usr/local/cpanel/scripts/cpservice', $service, 'stop' );

# Even if the init script doesn't exist, try to kill the service.
    if ( ssystem( 'killall', '-q', $service ) == 0 ) {
        sleep 1;
        ssystem( 'killall', '-q', '-9', $service );
        DEBUG "Killed $service";
    }

return;
}

sub touch {
    my $file = shift;

open( my $fh, ">>", $file ) or return;
    print {$fh} '';    # Must send something to the file or it doesn't save

foreach my $line (@_) {    # concat anything passed into the subroutine.
        print {$fh} $line;
    }
    close $fh;
}

sub usage {
    my $prog = $0;
    $prog =~ s{^.+/(.+)$}{$1};
    print "This script should not be called manually.\n";
    exit;
}

sub disable_and_remove_init_services {
    INFO "Disabling unneeded services...";

my @service_shutdown = qw(named);
    push @service_shutdown, qw(smail sendmail postfix master httpd apache wu-ftpd inetd ncsd)
      if ( !is_dnsonly() );

# Disable and remove the ncsd service.
    if ( ssystem( '/usr/local/cpanel/scripts/cpservice', 'nscd', 'status' ) == 0 ) {
        push @service_shutdown, 'ncsd';
        ssystem( '/usr/local/cpanel/scripts/cpservice', 'nscd', 'disable' );
    }

INFO "Stopping services:";
    foreach my $service (@service_shutdown) {
        os_service_stop($service);
    }

return;
}

sub display_howto {
    my $version = '';

if ( open( my $fh, "<", "/usr/local/cpanel/version" ) ) {
        $version = <$fh>;
        $version =~ s/^(\d+\.\d+).*/$1/gs;
    }

my $map = {
        version => $version,
        ip      => _get_public_ip(),
    };

my $howto = _howto_message($map);

foreach my $line ( split( "\n", $howto ) ) {
        INFO $line;
    }

return;
}

sub _howto_message {
    my $map = shift;

return <<EOM;
\e[0;36;40mCongratulations! Your installation of cPanel & WHM $map->{version} is now complete. The next step is to configure your server. \e[0m

Before you configure your server, ensure that your firewall allows access on port 2087.
On RHEL, CentOS, and CloudLinux systems, execute /scripts/configure_firewall_for_cpanel to accomplish this.

After ensuring that your firewall allows access on port 2087, you can configure your server.

1. Open your preferred browser

2. Type https://$map->{ip}:2087 in the address bar

3. Enter the word root in the Username text box

4. Enter your root password in the Password text box

5. Click the Login button

Visit https://go.cpanel.net/whminit for more information about first-time configuration of your server.

Visit http://support.cpanel.net or https://go.cpanel.net/whmfaq for additional support

Thank you for installing cPanel & WHM $map->{version}!

EOM
}

sub _get_public_ip {

# default value, when none will be parsed
    my $ip = '127.0.0.1';
    open( IPS, '-|' ) || exec( 'ifconfig', '-a' );

# only search for an IPv4 address
    while (<IPS>) {
        next unless m/inet\s+(addr:)?(([0-9]+)\.[0-9]+\.[0-9]+\.[0-9]+)\b/;
        next if $3 == 127;
        $ip = $2;
        last;
    }
    close(IPS);
    return Cpanel::NAT::get_public_ip($ip);
}

sub cpanel_config_actions {
    return qw/
      dormant_services eximmailtrap email_send_limits_count_mailman
      email_send_limits_defer_cutoff maxemailsperhour nobodyspam
      popbeforesmtpsenders skipbwlimitcheck jailprocmode jailmountusrbinsuid
      skipparentcheck enablecompileroptimizations signature_validation
      apache_port jailmountbinsuid userdirprotect
      enablefileprotect emailsperdaynotify
      /;
}

sub cpanel_config_post_actions {
    return qw/
      domainowner_mail_pass smtpmailgidonly usemysqloldpass phploader
      conserve_memory skipwebalizer skipanalog skipawstats popbeforesmtp
      email_send_limits_min_defer_fail_to_trigger_protection resetpass
      resetpass_sub invite_sub allow_deprecated_accesshash api_shell
      apache_port
      /;
}

# This subroutine helps document what action and post_action subs need to be run during a fresh install.
# A unit test will go off if you add a new one and don't update one of these subs
sub cpanel_config_ignored_actions {

# Post actions
    my @ignore = qw/ apache_ssl_port skipmailman skipspamassassin skipspambox disk_usage_include_mailman disk_usage_include_sqldbs
      allow_login_autocomplete autodiscover_proxy_subdomains emailarchive exim-retrytime ipv6_listen
      mycnf_auto_adjust_innodb_buffer_pool_size mycnf_auto_adjust_maxallowedpacket mycnf_auto_adjust_openfiles_limit
      php_max_execution_time php_post_max_size php_upload_max_filesize proxysubdomains skipboxtrapper
      skiphorde usemailformailmanurl autoupdate_certificate_on_hostname_mismatch global_dcv_rewrite_exclude
      server_locale xframecpsrvd pma_disableis/;

# Actions
    push @ignore, qw/allow_server_info_status_from autodiscover_host chkservd_check_interval jailapache skipdiskusage
      system_diskusage_critical_percent system_diskusage_warn_percent tcp_check_failure_threshold/;

push @ignore, 'requiressl';    # TODO: This one might need to run later?
    push @ignore, 'debughooks';    # TODO: This one might need to run later?

return @ignore;
}

sub do_cpanel_config_touch_files {
    my $cp_config  = scalar Cpanel::Config::LoadCpConf::loadcpconf();
    my $tweak_conf = \%Whostmgr::TweakSettings::Main::Conf;

# Block task queueing during a fresh install.
    no warnings 'redefine';
    local *Cpanel::ServerTasks::schedule_task = sub { };

# These actions expect a hash not a string to be passed in.
    $cp_config->{'dormant_services'} = { map { $_ => 1 } split /\s*,\s*/, $cp_config->{'dormant_services'} };
    $tweak_conf->{'dormant_services'}{'value'} = sub { {} };
    $cp_config->{'phploader'} = { map { $_ => 1 } split( /,/, $cp_config->{'phploader'} ) };

# Walk all the actions.
    foreach my $key ( cpanel_config_actions() ) {
        next if ( !exists $cp_config->{$key} );
        next if ( !$tweak_conf->{$key} );
        next if ( ref $tweak_conf->{$key}->{'action'} ne 'CODE' );
        DEBUG("Running defined action for cpanel.config key $key");

$tweak_conf->{$key}->{'action'}->( $cp_config->{$key} );
    }

# Walk all the post actions.
    foreach my $key ( cpanel_config_post_actions() ) {
        next if ( !exists $cp_config->{$key} );
        next if ( !$tweak_conf->{$key} );
        next if ( ref $tweak_conf->{$key}->{'post_action'} ne 'CODE' );

DEBUG("Running defined post_action for cpanel.config key $key");
        $tweak_conf->{$key}->{'post_action'}->( $cp_config->{$key}, undef, 1 );
    }

return;
}