^^&&^^

Edit File: mysqlpasswd

#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - mysqlpasswd                               Copyright 2010 cPanel, Inc.
#                                                           All rights Reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited

use strict;
use Cpanel::AccessIds::SetUids ();
use Cpanel::Config::LoadCpConf ();
use Cpanel::MysqlUtils         ();
use Cpanel::MysqlUtils::MyCnf  ();
use Cpanel::SafeRun::Simple    ();
use Cpanel::SafeRun::Full      ();
use Cpanel::Config::DBOwners   ();

if ( $> != 0 ) {
    die "Setting MySQL passwords is only possible using the root account\n";
}

my $mysqlbin;
if ( -x "/usr/local/bin/mysql" ) {
    $mysqlbin = '/usr/local/bin/mysql';
}
if ( -x "/usr/bin/mysql" ) {
    $mysqlbin = '/usr/bin/mysql';
}
if ( !$mysqlbin ) {
    die "Unable to locate a suitable mysql client binary!\n";
}

alarm(15);
my ( $user, $pass, $userhost );
if ( grep( /--multistdin/, @ARGV ) ) {
    $user = <STDIN>;
    chomp($user);
    $pass = <STDIN>;
    chomp($pass);
    $userhost = <STDIN>;
    chomp($userhost);
}
elsif ( !@ARGV ) {
    chomp( my $up = <STDIN> );
    my @UP = split( / /, $up );
    $user     = $UP[0];
    $pass     = $UP[1];
    $userhost = $UP[2];
}
else {
    $user     = $ARGV[0];
    $pass     = $ARGV[1];
    $userhost = $ARGV[2];
}
alarm(0);

if ( !$user ) { print STDERR "$0: user is blank\n"; exit 1; }
if ( !$pass ) { print STDERR "$0: pass is blank\n"; exit 1; }

my $quoted_user;
if ( $user eq 'root' ) {
    my $dbuser = Cpanel::MysqlUtils::getmydbuser('root') || 'root';
    $quoted_user = Cpanel::MysqlUtils::quote($dbuser);
}
else {
    $quoted_user = Cpanel::MysqlUtils::quote($user);
}
my $quoted_pass     = Cpanel::MysqlUtils::quote($pass);
my $quoted_userhost = Cpanel::MysqlUtils::quote($userhost);

my $cpuser = $user;
if ( $user ne 'root' ) {
    my $dbowners = Cpanel::Config::DBOwners::load_dbowner_to_user();
    $cpuser = $dbowners->{$user} || $user;
}

{
    local $SIG{'PIPE'} = 'IGNORE';
    open( my $mysql_fh, '|-' ) || exec( $mysqlbin, 'mysql' );
    if ( !$userhost ) {
        print $mysql_fh "UPDATE user SET Password=PASSWORD($quoted_pass) WHERE user=$quoted_user;\n";
    }
    else {
        print $mysql_fh "UPDATE user SET Password=PASSWORD($quoted_pass) WHERE user=$quoted_user AND host=$quoted_userhost;\n";
    }
    print $mysql_fh "FLUSH PRIVILEGES;\n";
    close($mysql_fh);
}

my ( $uid, $gid, $homedir ) = ( getpwnam($cpuser) )[ 2, 3, 7 ];

if ( defined $uid && $user eq $cpuser ) {
    my $host         = Cpanel::MysqlUtils::getmydbhost($cpuser);
    my $root_host    = Cpanel::MysqlUtils::getmydbhost('root');
    my @remote_hosts = _list_hosts_for_uid($uid);

if ( !$host || $host eq 'localhost' || $host eq $root_host || grep { $_ eq $host } @remote_hosts ) {
        if ($homedir) {
            my $cpconf_ref = Cpanel::Config::LoadCpConf::loadcpconf();
            if ( my $pid = fork() ) {
                waitpid( $pid, 0 );
            }
            else {
                my $dbuser = $cpuser;
                if ( $uid > 0 ) {
                    Cpanel::AccessIds::SetUids::setuids($cpuser);
                }
                else {
                    $dbuser = Cpanel::MysqlUtils::getmydbuser('root') || 'root';
                }

# Write ~/.my.cnf only for the root user
                if ( $user eq 'root' ) {
                    if ($host) {
                        Cpanel::MysqlUtils::MyCnf::update_mycnf(
                            user  => $cpuser,
                            items => [
                                {
                                    user => $dbuser,
                                    pass => $pass,
                                    host => $host,
                                }
                            ],
                        );
                    }
                    else {
                        Cpanel::MysqlUtils::MyCnf::update_mycnf(
                            user  => $cpuser,
                            items => [
                                {
                                    user => $dbuser,
                                    pass => $pass,
                                }
                            ],
                        );
                    }
                }

# Check for relocated root. Why, oh why change root's homedir???
                if ( $user eq 'root' ) {
                    if ( !-e '/root' ) {
                        mkdir '/root', 0700;
                    }
                    if ( $homedir ne '/root' && -d '/root' ) {
                        warn "Detected relocated /root directory ($homedir)\n";
                        system 'cp', '-f', '--', $homedir . '/.my.cnf', '/root/.my.cnf';
                    }
                }

exit;
            }
        }
    }
}

queue_dbstoregrants($cpuser);

sub queue_dbstoregrants {
    my $cpuser = shift;
    Cpanel::SafeRun::Full::run(
        'program' => '/usr/local/cpanel/bin/servers_queue',
        'args'    => [ '--plugin=MysqlTasks', 'queue', "dbstoregrants $cpuser" ],
    );
}

sub _list_hosts_for_uid {
    my ($uid) = @_;

return if $uid == 0;

return split( /\n/, Cpanel::SafeRun::Simple::saferun( '/usr/local/cpanel/bin/cpmysqladmin', $uid, 'LISTHOSTS' ) );
}